Sending Email

Sending emails in CFWheels is done from your controller files with the sendEmail() function. It's basically a wrapper around cfmail, but it has some smart functionality and a more CFWheels-like approach in general.
Getting this to work in CFWheels can be broken down in 3 steps. We'll walk you through them.
Establishing Mail Server and Account Information
We recommend using CFWheels ability to set global defaults for sendEmail() so that you don't have to specify more arguments than necessary in your controller files. Because it's likely that you will use the same mail server across your application, this makes it worthwhile to set a global default for it.
This setting should be done in the config/settings.cfm file and can look something like this:
Example
1
set(
2
    functionName="sendEmail",
3
    server="yourServer",
4
    username="yourUsername",
5
    password="yourPassword"
6
);
Copied!
By specifying these values here, these arguments can be omitted from all sendEmail() function calls, thus providing cleaner, less cluttered code.
But you are not limited to setting only these 3 variables. In fact, you can set a global default for any optional argument to  sendEmail() and since it accepts the same arguments that cfmail does. That's quite a few.
Alternatively, most modern CFML engines allow setting SMTP information directly within the application configuration. So you can actually add this in /config/app.cfm: here's an example configuration:
config/app.cfm
1
// Lucee:
2
this.tag.mail.server="smtp.mydomain.com";
3
this.tag.mail.username="mySMTPUsername";
4
this.tag.mail.password="mySMTPPassword";
5
this.tag.mail.port=587; // Optional port
6
this.tag.mail.usetls=true; // Optional TLS
7
​
8
// Adobe ColdFusion
9
this.smtpServersettings = {
10
    'server' : 'smtp.thedomain.com:2525',
11
    'username' : 'xxxxxxxx',
12
    'password' : 'xxxxxxx'
13
};
Copied!
Create an Email Template
An email template is required for sendEmail() to work and forms the basis for the mail message content. Think of an email template as the content of your email.
Templates may be stored anywhere within the /views/ folder, but we recommend a structured, logical approach. If different controllers utilize sendEmail()
and each require a unique template, place each email template within the views/controllername folder structure.
Consider this example scenario:
Controller:
Email Template:
Membership
/views/membership/myemailtemplate.cfm
Multiple templates may be stored within this directory should there be a need.
The content of the template is simple: simply output the content and any expected variables.
Here's an example for myemailtemplate.cfm, which will contain HTML content.
Example
1
<cfoutput>
2
<p>Hi #recipientName#,</p>
3
<p>
4
    We wanted to take a moment to thank you for joining our service
5
    and to confirm your start date.
6
</p>
7
<p>
8
    Our records indicate that your membership will begin on
9
    <strong>#DateFormat(startDate, "dddd, mmmm, d, yyyy")#</strong>.
10
</p>
11
</cfoutput>
Copied!
Sending the Email
As we've said before, sendEmail() accepts all attribute of CFML's cfmail tag as arguments. But it also accepts any variables that you need to pass to the email template itself.
Consider the following example:
Example
1
member = model("member").findByKey(newMember.id);
2
sendEmail(
3
    from="[email protected]",
4
    to=member.email,
5
    template="myemailtemplate",
6
    subject="Thank You for Becoming a Member",
7
    recipientName=member.name,
8
    startDate=member.startDate
9
);
Copied!
Here we are sending an email by including the myemailtemplate template and passing values for recipientNameand startDate to it.
Note that the template argument should be the path to the view's folder name and template file name without the extension. If the template is in the current controller, then you don't need to specify a folder path to the template file. In that case, just be sure to store the template file in the folder with the rest of the views for that controller.
The logic for which template file to include follows the same logic as the template argument to renderView().
Did you notice that we did not have to specify the type attribute of cfmail? CFWheels is smart enough to figure out that you want to send as HTML since you have tags in the email body. (You can override this behavior if necessary though by passing in the type argument.)
Multipart Emails
The intelligence doesn't end there though. You can have CFWheels send a multipart email by passing in a list of templates to the templates argument (notice the plural), and CFWheels will automatically figure out which one is text and which one is HTML.
Like the template argument, the logic for which file to include follows the same logic as the template argument to renderView().
Attaching Files
You can attach files to your emails as well by using the file argument (or files argument if you want multiple attachments). Simply pass in the name of a file that exists in the files folder (or a subfolder of it) of your application.
1
// Send files/termsAndConditions.pdf
2
sendEmail(
3
    to="[email protected]",
4
    from="[email protected]",
5
    template="/email/exampletemplate",
6
    subject="Test",
7
    files="termsAndConditions.pdf"
8
);
Copied!
Alternatively you can pass in mail parameters directly if you require more control (such as sending a dynamically generated PDF which isn't written to disk):
Mail Example
1
// Create PDF
2
cfdocument(name="PDFContent", format="pdf"){ 
3
  writeOutput("<h1>Cats are better than dogz!</h1>"); 
4
};
5
​
6
// Setup Mail Params
7
mailParams[1]["file"]= "Test.pdf";
8
mailParams[1]["type"]= "application/pdf";
9
mailParams[1]["content"]= PDFContent;
10
​
11
sendEmail(
12
    to="[email protected]",
13
    from="[email protected]",
14
    template="/email/exampletemplate",
15
    subject="Test",
16
    mailParams=mailParams
17
);
Copied!
Using Email Layouts
Much like the layouts outlined in the Layouts chapter, you can also create layouts for your emails.
A layout should be used just as the name implies: for layout and stylistic aspects of the email body. Based on the example given above, let's assume that the same email content needs to be sent twice.
Message is sent to a new member with a stylized header and footer.
A copy of message is sent to an admin at your company with a generic header
and footer.
Best practice is that variables (such as recipientName and startDate, in the example above) be placed as outputs in the template file.
In this case, the two calls to sendEmail() would be nearly identical, with the exception of the layout argument.
Example
1
// Get new member.
2
member = model("member").findByKey(params.key);
3
​
4
// Customer email with customized header/footer.
5
sendEmail(
6
    from="[email protected]",
7
    template="myemailtemplate",
8
    layout="customer",
9
    to=member.email,
10
    subject="Thank You for Becoming a Member",
11
    recipientName=member.name,
12
    startDate=member.startDate
13
);
14
​
15
// Plain text message with "admin" layout.
16
sendEmail(
17
    from="[email protected]",
18
    template="myemailtemplate",
19
    layout="admin",
20
    to="[email protected]",
21
    subject="Membership Verification: #member.name#",
22
    recipientName=member.name,
23
    startDate=member.startDate
24
);
Copied!
Multipart Email Layouts
CFWheels also lets you set up layouts for the HTML and plain text parts in a multipart email.
If we set up generic email layouts at views/plainemaillayout.cfm and views/htmlemaillayout.cfm, we would call sendEmail() like so:
Example
1
// Multipart customer email.
2
sendEmail(
3
    from="[email protected]",
4
    templates="/myemailtemplateplain,/myemailtemplatehtml",
5
    layouts="customerPlain,customerHtml",
6
    to=member.email,
7
    subject="Thank You for Becoming a Member",
8
    recipientName=member.name,
9
    startDate=member.startDate
10
);
Copied!
For both the templates and layouts arguments (again, notice the plurals), we provide a list of view files to use. CFWheels will figure out which of the templates and layouts are the HTML versions and separate out the MIME parts for you automatically.
Go Send Some Emails
Now you're all set to send emails the CFWheels way. Just don't be a spammer, please!

Handling Requests with Controllers - Previous

Sending Files

Next - Handling Requests with Controllers

Responding with Multiple Formats

Last modified 17d ago

Export as PDF

Copy link

Edit on GitHub

Contents

Establishing Mail Server and Account Information

Create an Email Template

Multipart Email Layouts

Go Send Some Emails