Nested Properties

When you're starting out as a Wheels developer, you are probably amazed at the simplicity of a model's CRUD methods. But then it all gets quite a bit more complex when you need to update records in multiple database tables in a single transaction.
Nested properties in Wheels makes this scenario dead simple. With a configuration using the nestedProperties()function in your model's config() method, you can save changes to that model and its associated models in a single call with save(), create(), or update().
One-to-One Relationships with Nested Properties
Consider a user model that has one profile:
models/User.cfc
1
component extends="Model" {
2
​
3
  function config() {
4
        hasOne("profile");
5
        nestedProperties(associations="profile");
6
    }
7
​
8
}
Copied!
By adding the call to nestedProperties() in the model, you can create both the user object and the profile object in a single call to create().
Setting up Data for the user Form in the Controller
First, in our controller, let's set the data needed for our form:
controllers/User.cfc
1
// In controllers/User.cfc 
2
function new() {
3
    var newProfile = model("profile").new();
4
    user = model("user").new(profile=newProfile);
5
}
Copied!
Because our form will also expect an object called profile nested within the user object, we must create a new instance of it and set it as a property in the call to user.new().
Also, because we don't intend on using the particular newProfile object set in the first line of the action, we can varscope it to clearly mark our intentions for its use.
If this were an edit action calling an existing object, our call would need to look similar to this:
controllers/User.cfc
1
function edit() {
2
    user = model("user").findByKey(key=params.key, include="profile");
3
}
Copied!
Because the form will also expect data set in the profile property, you must include that association in the finder call with the include argument.
Building a Form for Posting Nested Properties
For this example, our form at views/users/new.cfm will end up looking like this:
views/users/new.cfm
1
#startFormTag(action="create")#
2
​
3
    <!--- Data for user model --->
4
    #textField(label="First Name", objectName="user", property="firstName")#
5
    #textField(label="Last Name", objectName="user", property="lastName")#
6
​
7
    <!--- Data for associated profile model --->
8
    #textField(
9
        label="Twitter Handle",
10
        objectName="user",
11
        association="profile",
12
        property="twitterHandle"
13
    )#
14
    #textArea(
15
        label="Biography",
16
        objectName="user",
17
        association="profile",
18
        property="bio"
19
    )#
20
​
21
    <div>#submitTag(value="Create")#</div>
22
​
23
#endFormTag()#
Copied!
Of note are the calls to form helpers for the profile model, which contain an extra argument for association. This argument is available for all object-based form helpers. By using the association argument, Wheels will name the form field in such a way that the properties for the profile will be nested within an object in the user model.
Take a minute to read that last statement again. OK, let's move on to the action that handles the form submission.
Saving the Object and Its Nested Properties
You may be surprised to find out that our standard create action does not change at all from what you're used to.
controllers/Users.cfc
1
function create() {
2
    user = model("user").new(params.user);
3
    if ( user.save() ) {
4
        flashInsert(success="The user was created successfully.");
5
        redirectTo(controller=params.controller);
6
    } else {
7
        renderView(action="new");
8
    }
9
}
Copied!
When calling user.save() in the example above, Wheels takes care of the following:
Saves the data passed into the user model.
Sets a property on user called profile with the profile data stored in an object.
Saves the data passed into that profile model.
Wraps all calls in a transaction in case validations on any of the objects fail or something wrong happens with the database.
For the edit scenario, this is what our update action would look like (which is very similar to create):
controllers/Users.cfc
1
function update() {
2
    user = model("user").findByKey(params.user.id);
3
    if ( user.update(params.user) ) {
4
        flashInsert(success="The user was updated successfully.");
5
        redirectTo(action="edit");
6
    } else {
7
        renderView(action="edit");
8
    }
9
}
Copied!
One-to-Many Relationships with Nested Properties
Nested properties work with one-to-many associations as well, except now the nested properties will contain an array of objects instead of a single one. We know that one user can have many addresses. Furthermore, we know that each user has only one profile. 
In the user model, let's add an association called addresses and also enable it as nested properties.
models/User.cfc
1
component extends="Model" {
2
​
3
 function config() {
4
        hasOne("profile");
5
        hasMany("addresses");
6
        nestedProperties(
7
            associations="profile,addresses",
8
            allowDelete=true
9
        );
10
    }
11
​
12
}
Copied!
In this example, we have added the addresses association to the call to nestedProperties().
The addresses table contains a foreign key to the Users table called userid, Now in the addresses model, let's associate it with its parent User and also enable it as nested properties.
models/Address.cfc
1
component extends="Model" {
2
​
3
 function config() {
4
        belongsTo("User");
5
        nestedProperties(
6
            associations="User",
7
            allowDelete=true
8
        );
9
    }
10
​
11
}
Copied!
Setting up Data for the user Form in the Controller
Setting up data for the form is similar to the one-to-one scenario, but this time the form will expect an array of objects for the nested properties instead of a single object.
In this example, we'll just put one new address in the array.
controllers/Users.cfc
1
function new() {
2
    var newAddresses = [ model("address").new() ];
3
    user = model("user").new(addresses=newAddresses);
4
}
Copied!
In the edit scenario, we just need to remember to call the include argument to include the array of addresses saved for the particular user:
controllers/Users.cfc
1
function edit() {
2
    user = model("user").findByKey(key=params.key, include="addresses");
3
}
Copied!
Building the Form for the One-to-Many Association
This time, we'll add a section for addresses on our form:
views/users/_form.cfm
1
#startFormTag(action="create")#
2
​
3
    <!--- Data for `user` model --->
4
    <fieldset>
5
        <legend>User</legend>
6
​
7
        #textField(label="First Name", objectName="user", property="firstName")#
8
        #textField(label="Last Name", objectName="user", property="lastName")#
9
    </fieldset>
10
​
11
    <!--- Data for `address` models --->
12
    <fieldset>
13
        <legend>Addresses</legend>
14
​
15
        <div id="addresses">
16
            #includePartial(user.addresses)#
17
        </div>
18
    </fieldset>
19
​
20
    <div>#submitTag(value="Create")#</div>
21
​
22
#endFormTag()#
Copied!
In this case, you'll see that the form for addresses is broken into a partial. (See the chapter on Partials for more details.) Let's take a look at that partial.
The _address Partial
Here is the code for the partial at views/users/_address.cfm. Wheels will loop through each address in your nested properties and display this piece of code for each one.
views/users/_address.cfm
1
<div class="address">
2
    #textField(
3
        label="Street",
4
        objectName="user",
5
        association="addresses",
6
        position=arguments.current,
7
        property="address1"
8
    )#
9
    #textField(
10
        label="City",
11
        objectName="user",
12
        association="addresses",
13
        position=arguments.current,
14
        property="city"
15
    )#
16
    #textField(
17
        label="State",
18
        objectName="user",
19
        association="addresses",
20
        position=arguments.current,
21
        property="state"
22
    )#
23
    #textField(
24
        label="Zip",
25
        objectName="user",
26
        association="addresses",
27
        position=arguments.current,
28
        property="zip"
29
    )#
30
</div>
Copied!
Because there can be multiple addresses on the form, the form helpers require an additional argument for position. Without having a unique position identifier for each address, Wheels would have no way of understanding which state field matches with which particular address, for example.
Here, we're passing a value of arguments.current for position. This value is set automatically by Wheels for each iteration through the loop of addresses.
Auto-saving a Collection of Child Objects
Even with a complex form with a number of child objects, Wheels will save all of the data through its parent's save(), update(), or create() methods.
Basically, your typical code to save the user and its addresses is exactly the same as the code demonstrated in the Saving the Object and Its Nested Properties section earlier in this chapter.
Writing the action to save the data is clearly the easiest part of this process!
Transactions are Included by Default
As mentioned earlier, Wheels will automatically wrap your database operations for nested properties in a transaction. That way if something goes wrong with any of the operations, the transaction will rollback, and you won't end up with incomplete saves.
See the chapter on Transactions for more details.
Many-to-Many Relationships with Nested Properties
We all enter the scenario where we have "join tables" where we need to associate models in a many-to-many fashion. Wheels makes this pairing of entities simple with some form helpers.
Consider the many-to-many associations related to customers, publications, and subscriptions, straight from the Associations chapter.
1
//  models/Customer.cfc
2
component extends="Model" {
3
​
4
    public function config() {
5
        hasMany(name="subscriptions", shortcut="publications");
6
    }
7
​
8
}
9
//  models/Publication.cfc 
10
component extends="Model" {
11
​
12
    public function config() {
13
        hasMany("subscriptions");
14
    }
15
​
16
}
17
//  models/Subscription.cfc 
18
component extends="Model" {
19
​
20
    public function config() {
21
        belongsTo("customer");
22
        belongsTo("publication");
23
    }
24
​
25
}
Copied!
When it's time to save customers' subscriptions in the subscriptions join table, one approach is to loop through data submitted by checkBoxTag()s from your form, populate subscription model objects with the data, and call save(). This approach is valid, but it is quite cumbersome. Fortunately, there is a simpler way.
Setting up the Nested Properties in the Model
Here is how we would set up the nested properties in the customer model for this example:
models/Customer.cfc
1
component extends="Model" {
2
​
3
    public function config() {
4
        //  Associations 
5
        hasMany(name="subscriptions", shortcut="publications");
6
        //  Nested properties 
7
        nestedProperties(
8
            associations="subscriptions",
9
            allowDelete=true
10
        );
11
    }
12
​
13
}
Copied!
Setting up Data for the customer Form in the Controller
Let's define the data needed in an edit action in the controller at controllers/Customers.cfc.
controllers/Customers.cfc
1
function edit() {
2
    customer = model("customer").findByKey(
3
        key=params.key,
4
        include="subscriptions"
5
    );
6
    publications = model("publication").findAll(order="title");
7
}
Copied!
For the view, we need to pull the customer with its associated subscriptions included with the include argument. We also need all of the publications in the system for the user to choose from.
Building the Many-to-Many Form
We can now build a series of check boxes that will allow the end user choose which publications to assign to the customer.
The view template at views/customers/edit.cfm is where the magic happens. In this view, we will have a form for editing the customer and check boxes for selecting the customer's subscriptions.
views/customers/edit.cfm
1
<cfparam name="customer">
2
<cfparam name="publications" type="query">
3
​
4
<cfoutput>
5
​
6
#startFormTag(action="update")#
7
​
8
<fieldset>
9
    <legend>Customer</legend>
10
​
11
    #textField(
12
        label="First Name",
13
        objectName="customer",
14
        property="firstName"
15
    )#
16
    #textField(
17
        label="Last Name",
18
        objectName="customer",
19
        property="lastName"
20
    )#
21
</fieldset>
22
​
23
<fieldset>
24
    <legend>Subscriptions</legend>
25
​
26
    <cfloop query="publications">
27
        #hasManyCheckBox(
28
            label=publications.title,
29
            objectName="customer",
30
            association="subscriptions",
31
            keys="#customer.key()#,#publications.id#"
32
        )#
33
    </cfloop>
34
</fieldset>
35
​
36
<div>
37
    #hiddenField(objectName="customer", value="id")#
38
    #submitTag()#
39
</div>
40
​
41
#endFormTag()#
42
​
43
</cfoutput>
Copied!
The main point of interest in this example is the <fieldset> for Subscriptions, which loops through the query of publications and uses the hasManyCheckBox() form helper. This helper is similar to checkBox() and checkBoxTag(), but it is specifically designed for building form data related by associations. (Note that checkBox() is primarily designed for columns in your table that store a single true/false value, so that is the big difference.)
Notice that the objectName argument passed to hasManyCheckBox() is the parent customer object and the associations argument contains the name of the related association. Wheels will build a form variable named in a way that the customer object is automatically bound to the subscriptions association.
The keys argument accepts the foreign keys that should be associated together in the subscriptions join table. Note that these keys should be listed in the order that they appear in the database table. In this example, the subscriptions table in the database contains a composite primary key with columns called customerid and publicationid, in that order.
How the Form Submission Works
Handling the form submission is the most powerful part of the process, but like all other nested properties scenarios, it involves no extra effort on your part.
You'll notice that this example update action is fairly standard for a Wheels application:
controllers/Customers.cfc
1
function update() {
2
    //  Load customer object 
3
    customer = model("customer").findByKey(params.customer.id);
4
    /*  If update is successful, generate success message
5
        and redirect back to edit screen */
6
    if ( customer.update(params.customer) ) {
7
        redirectTo(
8
            action="edit",
9
            key=customer.id,
10
            success="#customer.firstName# #customer.lastName# record updated successfully."
11
        );
12
        //  If update fails, show form with errors 
13
    } else {
14
        renderView(action="edit");
15
    }
16
}
Copied!
In fact, there is nothing special about this. But with the nested properties defined in the model, Wheels handles quite a bit when you save the parent customer object:
Wheels will update the customers table with any changes submitted in the Customers <fieldset>.
Wheels will add and remove records in the subscriptions table depending on which check boxes are selected by the user in the Subscriptions <fieldset>.
All of these database queries will be wrapped in a Transaction . If any of the above updates don't pass validation or if the database queries fail, the transaction will roll back.